<%
' Cria uma instância de controle
Set AspPop3 = Server.CreateObject("POP3svg.Mailer")
' Endereço do Servidor de SMTP
AspPop3.RemoteHost = "mail.dominio.com.br"
' Endereço do E-mail
AspPop3.UserName = "email@dominio.com.br"
' Senha do E-mail
AspPop3.Password = "senha"

' Abre a Conexão com o Servidor
If AspPop3.OpenPop3 Then
  ' Total de Mensagens
  int_Mensagens = AspPop3.MessageCount
  ' Mostra a quantidade de mensagens no servidor
  Response.Write "<b>Existem "& int_Mensagens &" mensagens de e-mail no servidor.</b>" & VbCrLf

  ' Lista todas as Mensagens na tela.
  Response.Write "<table border=""1"">" & VbCrLf
  Response.Write "  <tr>" & VbCrLf
  Response.Write "    <th>Nº. Mensagem</th>" & VbCrLf
  Response.Write "    <th>Assunto</th>" & VbCrLf
  Response.Write "    <th>Enviada por</th>" & VbCrLf
  Response.Write "  </tr>" & VbCrLf
  For i = 1 To Cint(int_Mensagens)
    If AspPop3.Retrieve(i) Then
      Response.Write "  <tr>" & VbCrLf
      Response.Write "    <td>"& i &"</td>" & VbCrLf
      Response.Write "    <td>"& AspPop3.Subject &"</td>" & VbCrLf
      Response.Write "    <td>"& AspPop3.FromName &" ("& AspPop3.FromAddress &")</td>" & VbCrLf
      Response.Write "  </tr>" & VbCrLf
    End If
  Next 
  Response.Write "</table>"
Else
  ' Caso não tenha conseguido se conectar, exibe a mensagem
  Response.Write "Não foi possível a conexão ao servidor. Verifique os dados de acesso!"
End If

' Fecha a Conexão
AspPop3.ClosePop3
' Tira o objeto da memória
Set AspPop3 = Nothing
%>

<%
' Cria uma instância de controle
Set AspPop3 = Server.CreateObject("POP3svg.Mailer")
' Endereço do Servidor de SMTP
AspPop3.RemoteHost = "mail.dominio.com.br"
' Endereço do E-mail
AspPop3.UserName = "email@dominio.com.br"
' Senha do E-mail
AspPop3.Password = "senha"

' Abre a Conexão com o Servidor
If AspPop3.OpenPop3 Then
  ' Número da Mensagem
  int_Mensagem = 1

  ' Verifica se a mensagem realmente existe no servidor
  If AspPop3.Retrieve(int_Mensagem) Then
    ' Assunto da Mensagem
    Response.Write "<b>Assunto:</b> "& AspPop3.Subject &"<br />" & VbCrLf
    ' Remetente da Mensagem
    Response.Write "<b>Enviada Por:</b> "& AspPop3.FromName &" ("& AspPop3.FromAddress &")<br />" & VbCrLf
    ' Conteúdo da Mensagem
    Response.Write "<b>Conteúdo:</b> <pre>"& Server.HTMLEncode(AspPop3.BodyText) &"</pre>" & VbCrLf
  Else
    ' Caso a mensagem não exista
    Response.Write "A mensagem de número "& int_Mensagem &" não foi encontrada."
  End If

Else
  ' Caso não tenha conseguido se conectar, exibe a mensagem
  Response.Write "Não foi possível a conexão ao servidor. Verifique os dados de acesso!"
End If

' Fecha a Conexão
AspPop3.ClosePop3
' Tira o objeto da memória
Set AspPop3 = Nothing
%>