<%
' Cria uma instância do controle
Set AspTreeView = Server.CreateObject("obout_ASPTreeview_2.Tree")
' Nó raiz
AspTreeView.AddRootNode "Componentes ASP", "xpMyComp.gif"

' Depois populamos estes nós utilizando outro nó
AspTreeView.Add "root", "a0", "Manipulação de Arquivos XML", True
  AspTreeView.Add "a0", "a0_0", "MSXML - Microsoft"
  AspTreeView.Add "a0", "a0_1", "ASP XML Parser - Chilkat Software"
 
AspTreeView.Add "root", "a1", "Links", False, "book.gif"
  AspTreeView.Add "a1", "a1_0", "<a href='http://www.obout.com/'>Site do Fabricante</a>" , , "page.gif"
  AspTreeView.Add "a1", "a1_1", "<a href='http://www.obout.com/t2/download.aspx'>Download do Componente</a>" , , "page.gif"

' Localização das pasta de ícones
AspTreeView.FolderIcons = "icons/"
' Localização da pasta de estilos
AspTreeView.FolderStyle = "style/Classic/"
' Localização da pasta de scripts
AspTreeView.FolderScript = "script/"
' Largura utiliza pelo componente
AspTreeView.Width = "250px"
'Imprime o componente no página
Response.Write AspTreeView.HTML()
' Tira o objeto da memória
Set AspTreeView = Nothing
%>

<%	
sPath = Server.MapPath(Request.ServerVariables("Path_INFO"))
Do Until Right(sPath, 1) = "\"
  sPath = Left(sPath, Len(sPath) - 1)
Loop

i = Len(sPath) - 1
Do Until Mid(sPath, i, 1) = "\"
  sFolderName = Mid(sPath, i, Len(sPath) - i)
  i = i - 1
Loop

' Cria os objetos
Set oFSO = CreateObject("Scripting.FileSystemObject")
Set ot = Server.CreateObject("obout_asptreeview_2.tree")
ot.FolderIcons = "icons/"
ot.FolderScript = "script/"	
ot.FolderStyle = "style/Classic/"

ot.AddRootNode "<b style='color:navy;'>" & sFolderName & "</b>", true

' Exibe os diretórios e arquivos
Call AddFolder(sPath, "../" & Escape(sFolderName), "root")

' Mostra na tela o conteúdo da árvore
Response.Write ot.HTML
Set ot = Nothing
Set oFSO = Nothing

Function AddFolder(pth, dpt, parentID)
  Set oFolder = oFSO.GetFolder(pth)
  Set oSubFolder = oFolder.SubFolders
  Set oFile = oFolder.Files

  ' Listar pastas.
  For Each oItem In oSubFolder 
    iNode = iNode + 1
    ot.Add parentID, "z" & iNode, "<span onclick='ob_t23(this)'>" & oItem.Name & "</span>", false
    Call AddFolder(oItem.Path, dpt & "/" & Escape(oItem.Name), "z" & iNode)
  Next 

  ' Listar arquivos.
  For Each oF In oFile
    iNode = iNode + 1
    ot.Add parentID, "z" & iNode, "<a href=""" & dpt & "/" & Escape(oF.Name) & """>" & oF.Name & "</a>", , "page.gif"
  Next 
End Function
%>