<%
' Cria uma instância do controle
Set ChartDirector = Server.CreateObject("ChartDirector.API")
' Cria um array com os títulos do gráfico
array_Titulo = Array("Domínio 01", "Domínio 02", "Domínio 03", "Domínio 04", "Domínio 05")
' Cria um array com os valores do gráfico
array_Valores = Array(250, 190, 244, 85, 125)
' Informa o tamanho do gráfico
Set grafico = ChartDirector.PieChart(450, 220)
' Adiciona o título no rodapé do gráfico usando a fonte Arial Bold Italic
Call grafico.addTitle2(ChartDirector.Bottom, "Acesso aos Domínios", "arialbi.ttf")
' Informa que o gráfico será em 3D
Call grafico.set3D()
' Adiciona a caixa de legenda no canto superior esquerdo da imagem
Call grafico.addLegend(340, 10)
' Modifica o formato da etiqueta para $nnnK (pp.pp%)
Call grafico.setLabelFormat("{label} - {value}<*br*>({percent}%)")
' Define os titulos e os valores do gráfico
Call grafico.setData(array_Valores, array_Titulo)
' Explodir o primeiro item (valor = 0)
Call grafico.setExplode(0)
' Imprime a imagem do gráfico na tela
Response.ContentType = "image/png"
Response.BinaryWrite grafico.makeChart2(ChartDirector.PNG)
' Tira os objetos da memória
Set grafico = Nothing
Set ChartDirector = Nothing
%>

<%
' Cria uma instância do controle
Set ChartDirector = Server.CreateObject("ChartDirector.API")
' Cria um array com os títulos do gráfico
array_Titulo = Array("Domínio 01", "Domínio 02", "Domínio 03", "Domínio 04", "Domínio 05")
' Cria um array com os valores do gráfico
array_Valores = Array(250, 190, 244, 85, 125)
' Informa o tamanho do gráfico
Set grafico = ChartDirector.XYChart(400, 240)
' Adiciona o título do gráfico usando a fonte Times Bold Italic tamanho 14
Call grafico.addTitle("Acesso aos Domínios", "timesbi.ttf", 14)
' Define a área do gráfico e as cores de alternância no fundo
Call grafico.setPlotArea(45, 40, 300, 160, &Hf8f8f8, &Hffffff)
' Define os valores do gráfico e informa que cada barra terá uma cor
Set layer = grafico.addBarLayer3(array_Valores)
' Informa que o gráfico será em 3D com 15 pixels de profundidade
Call layer.set3D(15)
' Informa que o gráfica terá a forma circular (cilíndrica)
Call layer.setBarShape(ChartDirector.CircleShape)
' Informa os títulos do gráfico
Call grafico.xAxis().setLabels(array_Titulo)
' Adiciona o título esquerdo do gráfico
Call grafico.yAxis().setTitle("Nº de Acessos")
' Adiciona o título do rodapé do gráfico
Call grafico.xAxis().setTitle("Novembro de 2007")
' Imprime a imagem do gráfico na tela
Response.ContentType = "image/png"
Response.BinaryWrite grafico.makeChart2(ChartDirector.PNG)
' Tira os objetos da memória
Set layer = Nothing
Set grafico = Nothing
Set ChartDirector = Nothing
%>