Logomarca

Componentes ASP é um projeto de categorização e disponibilização de exemplos de componentes ActiveX, utilizados na programação ASP 3.0 (ASP Clássico): Todos os componentes possuem nome completo, descrição, versão, fabricante e exemplos. Seja muito bem-vindo(a) e aproveite nosso conteúdo.

Hospedagem de sites em ASP 3.0, ASP.Net 3.5 e PHP 5.2.13 no mesmo plano é na Rede2! Conheça: www.rede2.com.br


Aviso: Todos os componentes ASP catalogados estão disponíveis no provedor de hospedagem de sites Rede2.

Últimas Notícias:

  • - 18/03/2010 | Componentes ASP comemora 2 anos no ar, ajudando mais de 11 mil visitantes.
  • - 18/03/2008 | Categorizados 51 exemplos de 31 componentes ASP em 12 categorias.

Office Web Components (OWC) - Microsoft

O Microsoft Office Web Components é um conjunto de controles de Modelo de Objeto Componente (COM) usado na geração e publicação de planilhas e gráficos.

Gráfico em Formato de Pizza

<%
' Define as variáveis
Dim array_Titulo(4), array_Valores(4)

' Cria uma instância do controle
Set OfficeWeb = Server.CreateObject("OWC10.ChartSpace")
Set constants = OfficeWeb.Constants
OfficeWeb.Border.Color = constants.chColorNone

' Cria um array com os valores do gráfico
array_Valores(0) = 250
array_Valores(1) = 190
array_Valores(2) = 244
array_Valores(3) = 85
array_Valores(4) = 125

' Cria um array com os títulos do gráfico
array_Titulo(0) = "Domínio 01"
array_Titulo(1) = "Domínio 02"
array_Titulo(2) = "Domínio 03"
array_Titulo(3) = "Domínio 04"
array_Titulo(4) = "Domínio 05"

With OfficeWeb
  ' Inclui um objeto no gráfico
  .Charts.Add
  ' Tipo de grafico em coluna 3D
  .Charts(0).Type = OfficeWeb.Constants.chChartTypePie3d
  ' Incluindo série no gráfico
  .Charts(0).SeriesCollection.Add
  ' Definindo o titulo da série
  .Charts(0).SeriesCollection(0).Caption = "Acesso aos Domínios"
  ' Adicionando as categorias e os valores da série
  .Charts(0).SeriesCollection(0).SetData constants.chDimCategories, constants.chDataLiteral, array_Titulo
  .Charts(0).SeriesCollection(0).SetData constants.chDimValues, constants.chDataLiteral, array_Valores
  .Charts(0).HasLegend = True
  .Charts(0).HasTitle = True
End With

' Imprime a imagem do gráfico na tela
Response.ContentType = "image/gif"
Response.BinaryWrite OfficeWeb.GetPicture("gif", 300, 200)

' Tira os objetos da memória
Set constants = Nothing
Set OfficeWeb = Nothing
%>

Gráfico em Formato de Barras

<%
' Define as variáveis
Dim array_Titulo(4), array_Valores10(4), array_Valores11(4)

' Cria uma instância do controle
Set OfficeWeb = Server.CreateObject("OWC10.ChartSpace")
Set constants = OfficeWeb.Constants
OfficeWeb.Border.Color = constants.chColorNone

' Cria um array com os valores do gráfico do mês 10
array_Valores10(0) = 223
array_Valores10(1) = 177
array_Valores10(2) = 296
array_Valores10(3) = 109
array_Valores10(4) = 181

' Cria um array com os valores do gráfico do mês 11
array_Valores11(0) = 250
array_Valores11(1) = 190
array_Valores11(2) = 244
array_Valores11(3) = 85
array_Valores11(4) = 125

' Cria um array com os títulos do gráfico
array_Titulo(0) = "Domínio 01"
array_Titulo(1) = "Domínio 02"
array_Titulo(2) = "Domínio 03"
array_Titulo(3) = "Domínio 04"
array_Titulo(4) = "Domínio 05"

With OfficeWeb
  ' Inclui um objeto no gráfico
  .Charts.Add
  ' Tipo de grafico em coluna 3D
  .Charts(0).Type = OfficeWeb.Constants.chChartTypeColumn3d
  ' Incluindo série no gráfico
  .Charts(0).SeriesCollection.Add
  ' Definindo o titulo da série
  .Charts(0).SeriesCollection(0).Caption = "Mês 11"
  ' Adicionando as categorias e os valores da série
  .Charts(0).SeriesCollection(0).SetData constants.chDimCategories, constants.chDataLiteral, array_Titulo
  .Charts(0).SeriesCollection(0).SetData constants.chDimValues, constants.chDataLiteral, array_Valores11
End With

With OfficeWeb
  ' Incluindo série no gráfico
  .Charts(0).SeriesCollection.Add
  ' Definindo o titulo da série
  .Charts(0).SeriesCollection(1).Caption = "Mês 10"
  ' Adicionando as categorias e os valores da série
  .Charts(0).SeriesCollection(1).SetData constants.chDimCategories, constants.chDataLiteral, array_Titulo
  .Charts(0).SeriesCollection(1).SetData constants.chDimValues, constants.chDataLiteral, array_Valores10
End With

' Imprime a imagem do gráfico na tela
Response.ContentType = "image/gif"
Response.BinaryWrite OfficeWeb.GetPicture("gif", 700, 450)

' Tira os objetos da memória
Set constants = Nothing
Set OfficeWeb = Nothing
%>
Componente disponível no provedor de hospedagem de sites Rede2. Hospede Já!
Copyright© 2003 - 2010. Rede2 - Todos os direitos reservados

Rede2 é um provedor de HOSPEDAGEM DE SITES. Hospedagem profissional com hospedagem ASP, hospedagem ASP.Net (.NET 3.5). Outras tecnologias disponíveis: PHP, CGI, Perl, XML, HTML, banco de dados MySQL, banco de dados SQL Server. 15 dias de hospedagem de sites grátis.
Contrate qualquer plano de hospedagem e ganhe bônus de até R$ 70,00 para anunciar Google AdWords, R$ 100,00 no Yahoo e R$ 200,00 no Buscapé.